import groovy.json.JsonSlurper

plugins {
    id 'com.android.application'
    id 'org.jetbrains.kotlin.android'
}

android {
    namespace 'com.fankes.apperrorsdemo'
    compileSdk rootProject.ext.android.compileSdk
    ndkVersion rootProject.ext.android.ndkVersion

    signingConfigs {
        universal {
            def dirPath = rootProject.ext.app.signingConfigs.secretConfigsDirPath
            def fileName = rootProject.ext.app.signingConfigs.secretConfigsFileName
            def configs = new JsonSlurper().parse(file("${dirPath}/${fileName}"))
            keyAlias configs.keyAlias
            keyPassword configs.keyPassword
            storeFile file("${dirPath}/${configs.storeFileName}")
            storePassword configs.storePassword
            v1SigningEnabled true
            v2SigningEnabled true
        }
    }

    defaultConfig {
        applicationId 'com.fankes.apperrorsdemo'

        minSdk rootProject.ext.android.minSdk
        targetSdk rootProject.ext.android.targetSdk

        versionCode rootProject.ext.app.versionCode
        versionName rootProject.ext.app.versionName

        testInstrumentationRunner 'androidx.test.runner.AndroidJUnitRunner'
        consumerProguardFiles 'consumer-rules.pro'
    }

    buildTypes {
        debug {
            minifyEnabled false
            signingConfig signingConfigs.universal
        }
        release {
            minifyEnabled false
            signingConfig signingConfigs.universal
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
    }
    externalNativeBuild {
        cmake {
            path "src/main/cpp/CMakeLists.txt"
            version "3.22.1"
        }
    }
    compileOptions {
        sourceCompatibility JavaVersion.VERSION_11
        targetCompatibility JavaVersion.VERSION_11
    }
    kotlinOptions {
        jvmTarget = '11'
        freeCompilerArgs = [
                '-Xno-param-assertions',
                '-Xno-call-assertions',
                '-Xno-receiver-assertions'
        ]
    }
    buildFeatures {
        viewBinding true
    }
    lintOptions {
        checkReleaseBuilds false
    }
}

dependencies {
    implementation 'com.highcapable.yukireflection:api:1.0.2'
    implementation 'androidx.core:core-ktx:1.10.0'
    implementation 'androidx.appcompat:appcompat:1.6.1'
    implementation 'com.google.android.material:material:1.9.0'
    testImplementation 'junit:junit:4.13.2'
    androidTestImplementation 'androidx.test.ext:junit:1.1.5'
    androidTestImplementation 'androidx.test.espresso:espresso-core:3.5.1'
}