Initial commit

plugin-build/build.gradle.kts

@@ -0,0 +1,51 @@
+import io.gitlab.arturbosch.detekt.Detekt
+
+plugins {
+    alias(libs.plugins.kotlin) apply false
+    alias(libs.plugins.pluginPublish) apply false
+    alias(libs.plugins.detekt)
+    alias(libs.plugins.ktlint)
+    alias(libs.plugins.versionCheck)
+}
+
+allprojects {
+    group = property("GROUP").toString()
+    version = property("VERSION").toString()
+
+    apply {
+        plugin(rootProject.libs.plugins.detekt.get().pluginId)
+        plugin(rootProject.libs.plugins.ktlint.get().pluginId)
+    }
+
+    ktlint {
+        debug.set(false)
+        verbose.set(true)
+        android.set(false)
+        outputToConsole.set(true)
+        ignoreFailures.set(false)
+        enableExperimentalRules.set(true)
+        filter {
+            exclude("**/generated/**")
+            include("**/kotlin/**")
+        }
+    }
+
+    detekt {
+        config = rootProject.files("../config/detekt/detekt.yml")
+    }
+}
+
+tasks.withType<Detekt>().configureEach {
+    reports {
+        html.required.set(true)
+        html.outputLocation.set(file("build/reports/detekt.html"))
+    }
+}
+
+tasks.register("clean", Delete::class.java) {
+    delete(rootProject.buildDir)
+}
+
+tasks.wrapper {
+    distributionType = Wrapper.DistributionType.ALL
+}